ASM Player for msx-music

Page 3/3
1 | 2 |

By ro

Scribe (4544)

ro's picture

03-06-2009, 15:06

I do, man. I'm sure there's lotsa coders who have the MB1.44 replayer (ASM)

By JohnHassink

Ambassador (5591)

JohnHassink's picture

03-06-2009, 15:21

I'm sure of that too. I'm actually 100% sure of that.
Made me wonder if they keep it a secret on purpose. Big smile

By ro

Scribe (4544)

ro's picture

04-06-2009, 09:49

Okay, this is the source that looks most like the original, it's a bit altered to work with old kernel version (veeery old) but it'll do:

;  MB replayer v1.42 with RAMBIOS!
	ORG	5*16+$F87F
	DB	"MBPLAY15.ASM",0
;  -- System Info --
VDPBF1:	EQU	$F3DF	;  r#0-7
VDPBF2:	EQU	$FFE8-9	;  r#8-23
RUN:	EQU	$4000
	
	ORG	$C000
;  Globals in HIGHMEM.ASM
	DW	SMPADR	;  pointer
MUSADR:	DW	$8000	;  store
MUSPGE:	DB	3	;  store
CHIPS:	DB	2
HOKADR:	EQU	$C006	;  5 byte store
DRVERR:	EQU	$C00B
PROGS:	EQU	$C00D
ROMAN:	EQU	$C010
ALEX:	EQU	$C013
_GETMU:	EQU	$C016
BRKDMO:	EQU	$C200
CNTDMO:	EQU	$C203
	
;  # jumpers
	ORG	$D700
RBINIT:	DS	3
RBEXIT:	DS	3
SB_ROM:	DS	3
SB_RAM:	DS	3
JB_ROM:	DS	3
JB_RAM:	DS	3
CALLF:	DS	3
	
	ORG	$0800
	
	JP	STRMUS
	JP	HLTMUS
	JP	CNTMUS
	JP	STPMUS
	JP	FADMUS
	JP	S_R800
	JP	S_Z80
	
	DB	2
BUSPLY:	DB	0
	DB	3	; mapper
	DW	$8000	; adres
MBINTR:	LD	A,(BUSPLY)
	AND	A
	RET	Z
	JP	MUSINT
POS:	DB	0
STEP:	DB	0
STATUS:	DB	0,0,0	; 3 Statusbytes
STEPBF:	DS	13
	DW	LASPL1
	
FADMUS:	LD	(FADSPD),A
	LD	A,255
	LD	(FADING),A
	RET	
	
; +----- Start music -----+
STRMUS:	LD	A,(BUSPLY)
	AND	A
	RET	NZ
	
	LD	HL,0
	LD	(STATUS),HL
	LD	(STATUS+1),HL
	XOR	A
	LD	(SPDCNT),A
	LD	(FADING),A
	DEC	A
	LD	(POS),A
	LD	DE,0
	CALL	S_Z80
	
	LD	HL,CHNWC1
	LD	DE,CHNWC1+1
	LD	BC,9
	LD	(HL),0
	LDIR	
	LD	A,15
	LD	(STEP),A
	LD	(MAXPSG),A
	LD	A,48
	LD	(TPVAL),A
	
	IN	A,($FE)	;  Store mapper
	PUSH	AF
	LD	A,(MUSPGE)	;  Set new mapper
	OUT	($FE),A
	
	LD	HL,(MUSADR)
	LD	DE,XLENG
	LD	BC,207
	LDIR	
	
	LD	C,41
	ADD	HL,BC
	LD	C,128
	LDIR	
	LD	(XPOS),HL
	LD	A,(XLENG)
	INC	A
	LD	C,A
;        LD    b,0
	ADD	HL,BC
	LD	(PATADR),HL
	
;        LD    A,(&H2D)        ; turbo R?
;        CP    3
;        JR    C,STRMS2
;        CALL  &H0183          ; read CPU
;        OR    A
;        JR    Z,STRMS2
;        CALL  S_R800

	DI	
	LD	A,(CHIPS)
	OR	A
	CALL	Z,SETAUD
	DEC	A
	CALL	Z,SETMUS
	DEC	A
	CALL	Z,SETSTE
	
	LD	B,9
	LD	IY,XBEGVM+8
	LD	IX,XREVER
	LD	HL,LASPL1+200+6
	LD	DE,-30
MRLUS:	LD	(HL),0
	INC	HL
	INC	HL
	INC	HL
	LD	A,(IX+0)
	LD	(HL),A
	INC	HL
	LD	A,(IY+0)
	LD	(HL),A
	INC	HL
	LD	A,(IY+9)
	LD	(HL),A
	INC	IX
	DEC	IY
	ADD	HL,DE
	DJNZ	MRLUS
	
	CALL	SINSMM
	CALL	SINSPA
	LD	A,(XTEMPO)
	LD	(SPEED),A
	
	POP	AF	;  restore mapper
	OUT	($FE),A
	LD	A,255
	LD	(BUSPLY),A
	EI	
	RET	
	
; - Init start instr. Audio
SINSMM:	LD	DE,MMRGAD
	LD	HL,XBEGVM
	LD	IY,LASPL1+20
	
	LD	B,9
SINSM4:	PUSH	BC
	PUSH	HL
	PUSH	DE
	LD	B,(HL)
	LD	HL,XMMVOC-9
	LD	DE,9
SINSM3:	ADD	HL,DE
	DJNZ	SINSM3
	POP	DE
	
	PUSH	HL
	INC	HL
	INC	HL
	LD	A,(HL)
	LD	(IY+0),A
	INC	HL
	LD	A,(HL)
	LD	(IY+2),A
	LD	BC,5
	ADD	HL,BC
	LD	A,(HL)
	LD	(IY+4),A
	POP	HL
	
	LD	B,9
SINSM2:	LD	A,(DE)
	LD	C,A
	LD	A,(HL)
	INC	DE
	INC	HL
	CALL	MMOUT
	DJNZ	SINSM2
	POP	HL
	INC	HL
	LD	BC,25
	ADD	IY,BC
	POP	BC
	DJNZ	SINSM4
	
	LD	B,5
	LD	HL,STRREG
SINSM5:	LD	C,(HL)
	INC	HL
	LD	A,(HL)
	INC	HL
	CALL	FMMOUT
	DJNZ	SINSM5
	LD	A,255
	LD	(SMPVLM),A
	LD	A,(XSUST)
	AND	11000000
	LD	C,$BD
	JP	FMMOUT
	
; - Init start instr Music
SINSPA:	
	LD	HL,XBEGVP
	LD	IY,LASPL1+21
	LD	B,6
	LD	A,(XSUST)
	BIT	5,A
	PUSH	AF
	JR	NZ,SINSP2
	LD	B,9
SINSP2:	LD	C,$30
SINSPI:	PUSH	BC
	PUSH	HL
	LD	A,(HL)
	LD	HL,XPASTI-2
	ADD	A,A
	LD	C,A
	LD	B,0
	ADD	HL,BC
	LD	A,(HL)
	CP	16
	CALL	NC,SINSPO
	RLCA	
	RLCA	
	RLCA	
	RLCA	
	INC	HL
	LD	B,(HL)
	ADD	A,B
	RLC	B
	RLC	B
	LD	(IY+2),B
	LD	BC,25
	ADD	IY,BC
	POP	HL
	POP	BC
	CALL	PACOUT
	INC	HL
	INC	C
;        EI                    ; rip
;        HALT
	DJNZ	SINSPI
	
	XOR	A
	LD	C,$0E
	CALL	FPCOUT
	POP	AF
	RET	Z
	
	LD	DE,XDRVOL
	LD	HL,DRMREG
	LD	B,9
SETDRM:	LD	C,(HL)
	LD	A,(DE)
	CALL	PACOUT
	INC	HL
	INC	DE
	DJNZ	SETDRM
	
	LD	A,(XDRVOL)
	AND	$0F
	RLCA	
	RLCA	
	LD	(6*25+23+LASPL1),A
	LD	A,(XDRVOL+1)
	AND	$F0
	RRCA	
	RRCA	
	LD	(7*25+23+LASPL1),A
	LD	A,(XDRVOL+2)
	AND	$0F
	RLCA	
	RLCA	
	LD	(8*25+23+LASPL1),A
	RET	
	
SINSPO:	PUSH	HL
	SUB	15
	LD	B,A
	LD	HL,XORGP1-8
	LD	DE,8
SINPO2:	ADD	HL,DE
	DJNZ	SINPO2
	PUSH	HL
	INC	HL
	INC	HL
	LD	A,(HL)
	LD	(IY+0),A
	POP	HL
	LD	BC,$0800
SINPO3:	LD	A,(HL)
	CALL	PACOUT
	INC	C
	INC	HL
	DJNZ	SINPO3
	POP	HL
	XOR	A
	RET	
	
SETMUS:	PUSH	AF
	LD	A,(XSUST)
	AND	00100000
	LD	A,2
	JR	Z,SETAU2
	LD	HL,CHNWC1
	LD	DE,CHNWC1+1
	LD	BC,5
	LD	(HL),A
	LDIR	
	LD	(CHNWC1+9),A
	POP	AF
	RET	
SETAUD:	PUSH	AF
	INC	A
SETAU2:	LD	HL,CHNWC1
	LD	DE,CHNWC1+1
	LD	BC,9
	LD	(HL),A
	LDIR	
	POP	AF
	RET	
SETSTE:	LD	HL,XSTPR
	LD	DE,CHNWC1
	LD	BC,10
	LDIR	
	RET	
	
; +----- Continue Music -----+
CNTMUS:	LD	A,(BUSPLY)
	OR	A
	RET	NZ
	XOR	A
	LD	(BUSPLY),A
	RET	
; +----- Main (intr.) -----+
MUSINT:	
	IN	A,($FE)	;  store mapper
	PUSH	AF
	
	LD	A,(MUSPGE)
	OUT	($FE),A
	LD	A,(FADING)
	OR	A
	CALL	NZ,DOFADE
	CALL	DOPSG
	CALL	DOPIT
	
	LD	A,(VDPBF2+9)
	BIT	1,A
	JP	NZ,MSIN.0	;  nz,50 Hz
	LD	A,(FRQCNT)
	AND	A
	JP	Z,SKIP
	DEC	A
	LD	(FRQCNT),A
	JP	MSIN.0
	
SKIP:	LD	A,6
	LD	(FRQCNT),A
	JP	ENDINT
	
MSIN.0:	LD	A,(SPEED)
	LD	HL,SPDCNT
	INC	(HL)
	CP	(HL)
	JP	NZ,SECINT
	
	LD	(HL),0	;  Do new step
	LD	IY,LASPL1
	LD	HL,STEPBF
	LD	B,9
	LD	DE,CHNWC1
INTL1:	PUSH	BC
	LD	A,(HL)
	OR	A
	JP	Z,INTL3
	PUSH	DE
	PUSH	HL
	CP	97
	JP	C,ONEVN
	JP	Z,OFFEVT
	CP	114
	JP	C,CHGINS
	CP	177
	JP	C,CHGVOL
	CP	180
	JP	C,CHGSTE
	CP	199
	JP	C,LNKEVN
	CP	218
	JP	C,CHGPIT
	CP	224
	JP	C,CHGBR1
	CP	231
	JP	C,CHGREV
	CP	237
	JP	C,CHGBR2
	CP	238
	JP	C,SUSEVT
	JP	CHGMOD
	
INTL2:	POP	HL
	POP	DE
INTL3:	LD	BC,25
	ADD	IY,BC
	INC	DE
	INC	HL
	POP	BC
	DJNZ	INTL1
	CALL	MMDRUM
	LD	A,(DE)
	BIT	1,A
	CALL	NZ,PACDRM
	INC	HL
	LD	A,(HL)
	OR	A
	JR	Z,CMDINT
	CP	24
	JP	C,CHGTMP
	JP	Z,ENDOP2
	CP	28
	JP	C,CHGDRS
	CP	31
	JP	C,CHGSTA
	CALL	CHGTRS
CMDINT:	
ENDINT:	POP	AF	;  restore mapper
	OUT	($FE),A
	RET	
	
; - When not Step, decrunch
SECINT:	DEC	A
	CP	(HL)
	JR	NZ,ENDINT
	LD	A,(STEP)
	INC	A
	AND	$0F
	LD	(STEP),A
	LD	HL,(PATPNT)
	CALL	Z,POSRI3
	LD	DE,STEPBF
	LD	C,13
DCRSTP:	LD	A,(HL)
	CP	243
	JR	NC,CRCDAT
	LD	(DE),A
	INC	DE
	DEC	C
CRCDT2:	INC	HL
	LD	A,C
	OR	A
	JR	NZ,DCRSTP
	LD	(PATPNT),HL
	JP	SECIN2
CRCDAT:	SUB	242
	LD	B,A
	XOR	A
CRCLUS:	LD	(DE),A
	INC	DE
	DEC	C
	DJNZ	CRCLUS
	JR	CRCDT2
	
SECIN2:	LD	IY,LASPL1
	LD	HL,STEPBF
	LD	B,9
	LD	DE,CHNWC1
INTL4:	PUSH	BC
	LD	A,(HL)
	OR	A
	JR	Z,INTL5
	CP	97
	JR	NC,INTL5
	PUSH	HL
	LD	(IY+6),0
	LD	C,A
	PUSH	DE
	PUSH	BC
	LD	A,(DE)
	PUSH	AF
	AND	00000010
	CALL	NZ,PACPLE
	POP	AF
	POP	BC
	AND	00000001
	CALL	NZ,MMPLE
	POP	DE
	POP	HL
INTL5:	LD	BC,25
	ADD	IY,BC
	INC	DE
	INC	HL
	POP	BC
	DJNZ	INTL4
	JP	ENDINT
	
MMPLE:	LD	A,(TPVAL)
	ADD	A,C
	CP	96+48+1
	JR	C,MMPL4
	SUB	96
	JR	MMPL3
MMPL4:	CP	1+48
	JR	NC,MMPL3
	ADD	A,96
MMPL3:	SUB	48
	LD	(IY+0),A
	LD	HL,PAFREQ-1
	ADD	A,A
	ADD	A,L
	LD	L,A
	JR	NC,MMPL2
	INC	H
MMPL2:	LD	D,(HL)
	DEC	HL
	LD	E,(HL)
	EX	DE,HL
	ADD	HL,HL
	LD	A,L
	LD	E,(IY+9)
	ADD	A,E
	ADD	A,E
	LD	L,A
	DEC	HL
	LD	(IY+16),H
	LD	(IY+17),L
	RET	
	
PACPLE:	LD	A,(TPVAL)
	ADD	A,C
	CP	96+48+1
	JR	C,PACPL4
	SUB	96
	JR	PACPL3
PACPL4:	CP	1+48
	JR	NC,PACPL3
	ADD	A,96
PACPL3:	SUB	48
	LD	(IY+5),A
	LD	HL,PAFREQ-1
	ADD	A,A
	ADD	A,L
	LD	L,A
	JR	NC,PACPL2
	INC	H
PACPL2:	LD	A,(HL)
	LD	(IY+18),A
	DEC	HL
	LD	A,(HL)
	ADD	A,(IY+9)
	LD	(IY+19),A
	RET	
	
ONEVN:	LD	A,(DE)
	PUSH	AF
	AND	00000010
	CALL	NZ,PACPL
	POP	AF
	AND	00000001
	CALL	NZ,MMPL
	JP	INTL2
	
OFFEVT:	LD	(IY+6),0
	LD	A,(DE)
	PUSH	AF
	AND	00000010
	CALL	NZ,OFFPAP
OFFET2:	POP	AF
	AND	00000001
	CALL	NZ,OFFMMP
	JP	INTL2
	
SUSEVT:	LD	(IY+6),0
	LD	A,(DE)
	PUSH	AF
	AND	00000010
	CALL	NZ,SUSPAP
	JR	OFFET2
	
CHGINS:	PUSH	DE
	LD	(IY+6),0
	SUB	97
	LD	C,A
	LD	A,(DE)
	PUSH	AF
	PUSH	BC
	AND	00000010
	CALL	NZ,CHPACI
	POP	BC
	POP	AF
	AND	00000001
	CALL	NZ,CHMODI
	POP	DE
	JP	INTL2
	
CHGVOL:	PUSH	DE
	SUB	114
	LD	C,A
	LD	A,(DE)
	PUSH	AF
	PUSH	BC
	AND	00000010
	CALL	NZ,CHPACV
	POP	BC
	POP	AF
	AND	00000001
	CALL	NZ,CHMODV
	POP	DE
	JP	INTL2
	
CHGSTE:	LD	C,A
	LD	A,(CHIPS)
	CP	2
	JP	NZ,INTL2
	CALL	CHSTDP
	JP	INTL2
	
LNKEVN:	SUB	189
	LD	C,A
	PUSH	BC
	LD	A,(DE)
	PUSH	AF
	AND	00000010
	CALL	NZ,CHLKPA
	POP	AF
	POP	BC
	AND	00000001
	CALL	NZ,CHLKMM
	JP	INTL2
	
CHGPIT:	SUB	208
	LD	(IY+6),1
	LD	(IY+14),A
	RLCA	
	JR	C,CHGPI2
	LD	(IY+15),0
	JP	INTL2
CHGPI2:	LD	(IY+15),$FF
	LD	A,(DE)
	PUSH	AF
	AND	$02
	CALL	NZ,CHPIDP
	POP	AF
	AND	$01
	CALL	NZ,CHPIDM
	JP	INTL2
	
CHGBR1:	SUB	224
	JR	CHGBR3
CHGBR2:	SUB	230
CHGBR3:	PUSH	DE
	LD	C,A
	LD	A,(DE)
	PUSH	AF
	PUSH	BC
	AND	00000010
	CALL	NZ,CHPCBR
	POP	BC
	POP	AF
	AND	00000001
	CALL	NZ,CHMMBR
	POP	DE
	JP	INTL2
	
CHGREV:	SUB	227
	LD	(IY+9),A
	JP	INTL2
CHGMOD:	LD	(IY+6),2
	JP	INTL2
	
POSRI3:	LD	A,(XLENG)
	LD	B,A
	LD	A,(POS)
	CP	B
	JR	NZ,POSRI5
	LD	A,(XLOOP)
	CP	255
	JR	Z,POSRI4
	DEC	A
POSRI5:	INC	A
	LD	(POS),A
	LD	C,A
	LD	B,0
	LD	HL,(XPOS)
	ADD	HL,BC
	LD	A,(HL)
	DEC	A
	ADD	A,A
	LD	C,A
	LD	HL,(PATADR)
	ADD	HL,BC
	LD	E,(HL)
	INC	HL
	LD	D,(HL)
	EX	DE,HL
	LD	DE,(MUSADR)
	ADD	HL,DE
	RET	
POSRI4:	XOR	A
	LD	(BUSPLY),A
	DEC	A
	JR	POSRI5
	
;  - - - MSX Audio - - -
;  - Play note
MMPL:	LD	A,(IY+17)
	LD	C,(IY+7)
	CALL	FMMOUT
	
	LD	(IY+1),A
	SET	4,C
	LD	A,(IY+16)
	CALL	FMMOUT
	SET	5,A
	LD	(IY+2),A
	JP	FMMOUT
	
;  - OFF
OFFMMP:	LD	C,(IY+7)
	LD	A,(IY+1)
	CALL	FMMOUT
	LD	A,(IY+2)
	SET	4,C
	AND	11011111
	LD	(IY+2),A
	JP	FMMOUT
	
;  - New instr.
CHMODI:	LD	A,C
	PUSH	BC
	LD	(IY+10),A
	LD	B,A
	LD	HL,XMMVOC-9
	LD	DE,9
CHMOI2:	ADD	HL,DE
	DJNZ	CHMOI2
	POP	BC
	PUSH	HL
	
	INC	HL	;  Brightness
	INC	HL
	LD	A,(HL)
	LD	(IY+20),A
	
	LD	A,10
	SUB	B
	LD	B,A
	LD	HL,MMRGAD-9
	LD	DE,9
CHMOI3:	ADD	HL,DE
	DJNZ	CHMOI3
	POP	DE
	
	LD	B,9
CHMOI4:	LD	C,(HL)
	LD	A,(DE)
	CALL	FMMOUT
	INC	HL
	INC	DE
	DJNZ	CHMOI4
	EX	DE,HL
	DEC	HL
	LD	A,(HL)
	LD	(IY+24),A
	LD	DE,-5
	ADD	HL,DE
	LD	B,(IY+22)
	LD	A,(HL)
	LD	(IY+22),A
	LD	A,(FADING)
	OR	A
	RET	Z
	
	LD	A,(HL)
	AND	00111111
	LD	C,A
	LD	A,B
	AND	00111111
	CP	C
	RET	C
	LD	(IY+22),B
	LD	A,B
	LD	C,(IY+13)
	JP	FMMOUT
	
;  - Volume
CHMODV:	LD	A,C
	EX	AF,AF
	LD	B,(IY+10)
	LD	HL,XMMVOC-6
	LD	DE,9
CHMOV2:	ADD	HL,DE
	DJNZ	CHMOV2
	LD	A,(HL)
	AND	11000000
	LD	C,(IY+13)
	EX	AF,AF
	ADD	A,B
	CALL	FMMOUT
	LD	C,(IY+22)
	LD	(IY+22),A
	LD	A,(FADING)
	OR	A
	RET	Z
	
	LD	A,B
	AND	00111111
	LD	B,A
	LD	A,C
	AND	00111111
	CP	B
	RET	C
	LD	(IY+22),C
	LD	A,C
	LD	C,(IY+13)
	JP	FMMOUT
	
;  - Stereo set
CHSTDP:	LD	(IY+6),0
	LD	A,C
	SUB	176
	LD	(DE),A
	PUSH	AF
	AND	1
	CALL	Z,MODUIT
	POP	AF
	AND	2
	CALL	Z,MSXUIT
	RET	
	
;  - Link
CHLKMM:	LD	A,(IY+0)
	ADD	A,C
	LD	(IY+0),A
	LD	HL,PAFREQ-1
	ADD	A,A
	ADD	A,L
	LD	L,A
	JR	NC,CHLKM2
	INC	H
CHLKM2:	PUSH	DE
	LD	D,(HL)
	DEC	HL
	LD	E,(HL)
	EX	DE,HL
	ADD	HL,HL
	DEC	HL
	POP	DE
	LD	A,H
	LD	(MMFRQS),A
	LD	A,L
	LD	H,(IY+9)
	ADD	A,H
	ADD	A,H
	LD	(IY+1),A
	LD	C,(IY+7)
	CALL	FMMOUT
	SET	4,C
	LD	A,(MMFRQS)
	OR	00100000
	LD	(IY+2),A
	LD	(IY+6),0
	JP	FMMOUT
	
;  - Brightness
CHMMBR:	LD	A,(IY+20)
	AND	11000000
	LD	E,A
	LD	A,(IY+20)
	AND	00111111
	LD	B,A
	LD	A,C
	ADD	A,B
	ADD	A,E
	LD	(IY+20),A
	LD	C,(IY+13)
	DEC	C
	DEC	C
	DEC	C
	JP	FMMOUT
	
;  - Pitch ON
CHPIDM:	LD	H,(IY+2)
	BIT	1,H
	RET	NZ
	LD	A,H
	AND	11111100
	SUB	4
	LD	L,(IY+1)
	RES	5,H
	ADD	HL,HL
	LD	(IY+1),L
	EX	AF,AF
	LD	A,H
	AND	00000011
	LD	H,A
	EX	AF,AF
	OR	H
	LD	(IY+2),A
	RET	
	
;  - Samps
MMDRUM:	LD	A,(DE)
	RRCA	
	JR	NC,NOMMDR
	LD	A,(HL)
	OR	A
	JP	Z,MMDRU2
	EXX	
	LD	HL,MMPDT1-2
	ADD	A,A
	LD	C,A
	LD	B,0
	RL	B
	ADD	HL,BC
	LD	A,(HL)
	LD	C,$11
	CALL	FMMOUT
	INC	HL
	LD	A,(HL)
	DEC	C
	CALL	FMMOUT
	EXX	
	
MMDRU2:	INC	HL
	LD	A,(HL)
	OR	A
	JP	Z,MMDRU3

	SCF	
	RLA	
	LD	B,A
	LD	A,(SMPVLM)
	CP	B
	JR	C,MMDRU4
	LD	A,B
MMDRU4:	LD	C,$12
	CALL	FMMOUT
MMDRU3:	INC	HL
	LD	A,(HL)
	AND	11110000
	OR	A
	RET	Z
	SRL	A
	SRL	A
	SRL	A
	SRL	A
	EXX	
	CALL	MDRBLK
	EXX	
	LD	C,7
	LD	A,1
	CALL	FMMOUT
	LD	A,$A0
	JP	FMMOUT
NOMMDR:	INC	HL
	INC	HL
	RET	
	
MDRBLK:	ADD	A,A
	ADD	A,A
	LD	HL,SMPADR-4
	LD	C,A
	LD	B,0
	ADD	HL,BC
	LD	C,9
	LD	A,(HL)
	CALL	FMMOUT
	INC	HL
	LD	A,(HL)
	INC	C
	CALL	FMMOUT
	INC	HL
	LD	A,(HL)
	INC	C
	CALL	FMMOUT
	INC	HL
	LD	A,(HL)
	INC	C
	JP	FMMOUT
	
;  - - - MSX Music - - -
;  - Play note
PACPL:	LD	A,(IY+19)
	LD	C,(IY+8)
	CALL	FPCOUT
	LD	(IY+3),A
	LD	A,C
	ADD	A,$10
	LD	C,A
	LD	A,(IY+18)
	CALL	FPCOUT
	SET	4,A
	LD	(IY+4),A
	JP	FPCOUT
	
;  - SUS
SUSPAP:	LD	L,00100000
	JR	OFFPA2
	
;  - OFF
OFFPAP:	LD	L,0
OFFPA2:	LD	C,(IY+8)
	LD	A,(IY+3)
	CALL	FPCOUT
	LD	A,C
	ADD	A,$10
	LD	C,A
	LD	A,(IY+4)
	AND	11101111
	OR	L
	LD	(IY+4),A
	JP	FPCOUT
	
;  - New instr.
CHPACI:	PUSH	BC
	CALL	OFFPAP
	POP	BC
	LD	A,C
	LD	(IY+11),A
	DEC	A
	ADD	A,A
	LD	C,A
	LD	B,0
	LD	HL,XPASTI
	ADD	HL,BC
	LD	A,(HL)
	CP	16
	JP	NC,CHPACO
	RLCA	
	RLCA	
	RLCA	
	RLCA	
CHPAI2:	INC	HL	;  Hardware Instr.
	LD	C,(HL)
	LD	L,A
	ADD	A,C
	PUSH	BC
	LD	C,(IY+12)
	CALL	FPCOUT
	POP	BC
	RLC	C
	RLC	C
	LD	B,(IY+23)
	LD	(IY+23),C
	LD	A,(FADING)
	OR	A
	RET	Z
	LD	A,B
	CP	C
	RET	C
	LD	(IY+23),B
	SRL	B
	SRL	B
	LD	A,L
	ADD	A,B
	LD	C,(IY+12)
	JP	FPCOUT
	
CHPACO:	EXX		;  Original Instr.
	SUB	15
	RLCA	
	RLCA	
	RLCA	
	LD	B,0
	LD	C,A
	LD	HL,XORGP1-8
	ADD	HL,BC
	
	PUSH	HL	;  Brightness
	INC	HL
	INC	HL
	LD	A,(HL)
	LD	(IY+21),A
	POP	HL
	
	LD	BC,$0800
CHPAO3:	LD	A,(HL)
	CALL	FPCOUT
	INC	C
	INC	HL
	DJNZ	CHPAO3
	EXX	
	XOR	A
	JP	CHPAI2
	
;  - Volume
CHPACV:	LD	A,C
	PUSH	AF
	SRL	A
	SRL	A
	EX	AF,AF
	LD	A,(IY+11)
	LD	B,0
	ADD	A,A
	LD	C,A
	LD	HL,XPASTI-2
	ADD	HL,BC
	LD	A,(HL)
	CP	16
	JR	C,CHPCV2
	XOR	A
CHPCV2:	RLCA	
	RLCA	
	RLCA	
	RLCA	
	LD	B,A
	LD	C,(IY+12)
	EX	AF,AF
	XOR	B
	CALL	FPCOUT
	LD	L,B
	POP	BC
	LD	C,(IY+23)
	LD	(IY+23),B
	LD	A,(FADING)
	OR	A
	RET	Z
	
	LD	A,C
	CP	B
	RET	C
	LD	(IY+23),C
	LD	A,C
	SRL	A
	SRL	A
	XOR	L
	LD	C,(IY+12)
	JP	FPCOUT
	
;  - Link
CHLKPA:	LD	A,(IY+5)
	ADD	A,C
	LD	(IY+5),A
	
	LD	HL,PAFREQ-1
	ADD	A,A
	ADD	A,L
	LD	L,A
	JR	NC,CHLKP2
	INC	H
CHLKP2:	LD	A,(HL)
	LD	(MMFRQS),A
	DEC	HL
	LD	A,(HL)
	ADD	A,(IY+9)
	LD	(IY+3),A
	LD	C,(IY+8)
	CALL	FPCOUT
	LD	A,C
	ADD	A,$10
	LD	C,A
	LD	A,(MMFRQS)
	OR	00010000
	LD	(IY+4),A
	LD	(IY+6),0
	JP	FPCOUT
	
;  - Brightnes
CHPCBR:	LD	A,(IY+11)
	DEC	A
	ADD	A,A
	LD	E,A
	LD	D,0
	LD	HL,XPASTI
	ADD	HL,DE
	LD	A,(HL)
	CP	16
	RET	C
	LD	A,(IY+21)
	AND	11000000
	LD	E,A
	LD	A,(IY+21)
	AND	00111111
	LD	B,A
	LD	A,C
	ADD	A,B
	ADD	A,E
	LD	(IY+21),A
	LD	C,2
	JP	FPCOUT
	
;  - Pitch bending
CHPIDP:	LD	A,(IY+4)
	BIT	0,A
	RET	NZ
	DEC	A
	LD	(IY+4),A
	LD	A,(IY+3)
	ADD	A,A
	LD	(IY+3),A
	RET	
	
;  - Drum
PACDRM:	LD	A,(HL)
	AND	00001111
	OR	A
	RET	Z
	LD	E,A
	LD	D,0
	PUSH	HL
	LD	HL,XDRBLK-1
	ADD	HL,DE
	LD	A,(HL)
	CP	00100000
	LD	C,A
	CALL	NC,PSGDRM
	POP	HL
	LD	A,(XSUST)
	AND	00100000
	RET	Z
	LD	A,C
	AND	00011111
	LD	C,$0E
	CALL	FPCOUT
	SET	5,A
	JP	FPCOUT
	
;  - - - PSG - - -
PSGDRM:	RLCA	
	RLCA	
	RLCA	
	AND	00000111
	ADD	A,A
	LD	E,A
	LD	HL,PSGADR-2
	ADD	HL,DE
	LD	E,(HL)
	INC	HL
	LD	D,(HL)
	EX	DE,HL
	LD	A,(HL)
	LD	(PSGCNT),A
	INC	HL
	LD	B,(HL)
	INC	HL
PSGL1:	LD	A,(HL)
	OUT	($A0),A
	INC	HL
	LD	A,(HL)
	OUT	($A1),A
	INC	HL
	DJNZ	PSGL1
	LD	A,(MAXPSG)
	LD	B,A
	LD	A,(HL)
	CP	B
	JR	C,PSGDR2
	LD	A,B
PSGDR2:	LD	(PSGVOL),A
	JP	DOPSG2
	
;  - - - Command routs - - -
;  - Tempo
CHGTMP:	LD	B,A
	LD	A,25
	SUB	B
	LD	(SPEED),A
	JP	CMDINT
;  - ENDOP
ENDOP2:	LD	A,15
	LD	(STEP),A
	JP	CMDINT
;  - DRMSET
CHGDRS:	SUB	25
	ADD	A,A
	LD	B,A
	ADD	A,A
	ADD	A,B
	LD	E,A
	LD	D,0
	LD	HL,XDRFRQ
	ADD	HL,DE
	EX	DE,HL
	LD	HL,DRMREG+3
	LD	B,6
CHGDRL:	LD	C,(HL)
	LD	A,(DE)
	CALL	FPCOUT
	INC	HL
	INC	DE
	DJNZ	CHGDRL
	JP	CMDINT
	
;  - Status bytes
CHGSTA:	LD	C,A
	LD	B,0
	LD	HL,STATUS-28
	ADD	HL,BC
	LD	(HL),255
	JP	CMDINT
	
;  - Transpose
CHGTRS:	SUB	55-48
	LD	(TPVAL),A
	RET	
	
; +----- This rout every vbl -----+
;  - - - Fade out - - -
DOFADE:	LD	A,(FADSPD)
	LD	B,A
	LD	A,(FADCNT)
	INC	A
	LD	(FADCNT),A
	CP	B
	RET	NZ
	XOR	A
	LD	(FADCNT),A
	LD	IY,LASPL1
	LD	B,9
	LD	HL,0
DOFADL:	PUSH	BC
	LD	A,(IY+22)
	AND	11000000
	LD	B,A
	LD	A,(IY+22)
	AND	00111111
	ADD	A,2
	CP	64
	JR	C,DOFAD2
	LD	A,63
DOFAD2:	LD	C,(IY+13)
	ADD	A,B
	LD	(IY+22),A
	CALL	FMMOUT
	LD	B,A
	LD	A,(IY+24)
	BIT	0,A
	CALL	NZ,DOFADA
	LD	A,B
	AND	00111111
	XOR	63
	LD	E,A
	LD	D,0
	ADD	HL,DE
	POP	BC
	PUSH	BC
	LD	A,B
	CP	3
	JR	NC,DOFAD6
	LD	A,(XSUST)
	BIT	5,A
	JP	NZ,DOFAD8
DOFAD6:	PUSH	HL
	LD	A,(IY+11)
	DEC	A
	ADD	A,A
	LD	C,A
	LD	B,0
	LD	HL,XPASTI
	ADD	HL,BC
	LD	A,(HL)
	CP	16
	JR	C,DOFAD5
	XOR	A
DOFAD5:	RLCA	
	RLCA	
	RLCA	
	RLCA	
	LD	B,A
	LD	A,(IY+23)
	ADD	A,2
	CP	64
	JR	C,DOFAD3
	LD	A,63
DOFAD3:	LD	(IY+23),A
	SRL	A
	SRL	A
	LD	C,(IY+12)
	ADD	A,B
	CALL	FPCOUT
	POP	HL
	AND	00001111
	XOR	15
	LD	E,A
	LD	D,0
	ADD	HL,DE
	LD	BC,25
	ADD	IY,BC
	POP	BC
	DEC	B
	JP	NZ,DOFADL
	
	LD	A,(SMPVLM)
	SUB	12
	JR	NC,DOFAD4
	XOR	A
DOFAD4:	LD	(SMPVLM),A
	LD	C,$12
	CALL	FMMOUT
	LD	A,(MAXPSG)
	OR	A
	JR	NZ,DOFAD9
	LD	A,1
DOFAD9:	DEC	A
	LD	(MAXPSG),A
	LD	DE,0
	RST	$20
	RET	NZ
	XOR	A
	LD	(BUSPLY),A
	RET	
	
DOFAD8:	PUSH	HL
	LD	A,(IY+23)
	SRL	A
	SRL	A
	JP	DOFAD5
	
DOFADA:	LD	A,(IY+20)
	AND	11000000
	LD	C,A
	LD	A,(IY+20)
	AND	00111111
	ADD	A,2
	CP	64
	JR	C,DOFADB
	LD	A,63
DOFADB:	ADD	A,C
	LD	(IY+20),A
	LD	C,(IY+13)
	DEC	C
	DEC	C
	DEC	C
	JP	FMMOUT
	
;  - PSG
DOPSG:	LD	A,(PSGCNT)
	OR	A
	RET	Z
	DEC	A
	LD	(PSGCNT),A
	JR	Z,ENDPSG
DOPSG2:	LD	A,8
	OUT	($A0),A
	LD	A,(PSGVOL)
	CP	4
	JR	NC,DOPSG3
	LD	A,4
DOPSG3:	SUB	2
	LD	(PSGVOL),A
TRBPSG:	NOP		;  (tr: DEC A 2*)
	NOP	
	OUT	($A1),A
	RET	
ENDPSG:	LD	A,7
	OUT	($A0),A
	LD	A,255
	OUT	($A1),A
	LD	A,8
	OUT	($A0),A
	XOR	A
	OUT	($A1),A
	RET	
	
;  - - - do Pitch - - -
DOPIT:	LD	IY,LASPL1
	LD	DE,CHNWC1
	EXX	
	LD	B,9
	LD	DE,25
DOPITL:	EXX	
	LD	A,(IY+6)
	LD	H,A
	OR	A
	JP	Z,DOPIT2
	LD	A,(DE)
	AND	00000001
	CALL	NZ,PITMM
	LD	A,(DE)
	AND	00000010
	CALL	NZ,PITPA
DOPIT2:	INC	DE
	EXX	
	ADD	IY,DE
	DJNZ	DOPITL
	RET	
	
;  - Audio
PITMM:	PUSH	HL
	DEC	H
	JR	NZ,MODMM
	LD	L,(IY+14)
	LD	H,(IY+15)
	LD	C,(IY+1)
	LD	B,(IY+2)
	BIT	7,H
	JR	NZ,PITMM2
	ADD	HL,HL
	ADD	HL,BC
	LD	A,B
	AND	00000010
	LD	B,A
PITMM4:	LD	(IY+1),L
	LD	C,(IY+7)
	LD	A,L
	CALL	FMMOUT
	LD	A,H
	OR	B
	LD	(IY+2),A
	SET	4,C
	POP	HL
	JP	FMMOUT
	
PITMM2:	ADD	HL,HL
	ADD	HL,BC
	BIT	1,H
	JR	NZ,PITMM3
	DEC	H
	DEC	H
PITMM3:	LD	B,0
	JP	PITMM4
	
;  - MSX Music
PITPA:	DEC	H
	JR	NZ,MODPA
	LD	L,(IY+14)
	LD	H,(IY+15)
	LD	C,(IY+3)
	LD	B,(IY+4)
	BIT	7,H
	JR	NZ,PITPA2
	ADD	HL,BC
	LD	A,B
	AND	00000001
	LD	B,A
PITPA4:	LD	(IY+3),L
	LD	C,(IY+8)
	LD	A,L
	CALL	FPCOUT
	LD	A,C
	ADD	A,$10
	LD	C,A
	LD	A,H
	OR	B
	LD	(IY+4),A
	JP	FPCOUT
PITPA2:	ADD	HL,BC
	BIT	0,H
	JR	NZ,PITPA3
	DEC	H
PITPA3:	LD	B,0
	JP	PITPA4
	
;  - MOD Audio
MODMM:	LD	A,H
	ADD	A,2
	CP	12
	JR	NZ,MODMM3
	LD	A,2
MODMM3:	LD	(IY+6),A
	LD	A,H
	ADD	A,A
	LD	C,A
	LD	B,0
	LD	HL,MODVAL-2
	ADD	HL,BC
	LD	C,(HL)
	SLA	C
	INC	HL
	LD	B,(HL)
	LD	L,(IY+1)
	LD	H,(IY+2)
	ADD	HL,BC
	LD	B,0
	JP	PITMM4
	
;  - MOD Music
MODPA:	LD	A,(DE)
	CP	2
	JR	NZ,MODPA2
	LD	A,H
	ADD	A,2
	CP	12
	JR	NZ,MODPA3
	LD	A,2
MODPA3:	LD	(IY+6),A
MODPA2:	LD	A,H
	ADD	A,A
	LD	C,A
	LD	B,0
	LD	HL,MODVAL-2
	ADD	HL,BC
	LD	C,(HL)
	INC	HL
	LD	B,(HL)
	LD	L,(IY+3)
	LD	H,(IY+4)
	ADD	HL,BC
	LD	B,0
	JP	PITPA4
	
;  Routines with R800
S_R800:	LD	HL,PAROUT
	LD	(PACOUT+1),HL
	LD	(FPCOUT+1),HL
	LD	HL,MMROUT
	LD	(MMOUT+1),HL
	LD	(FMMOUT+1),HL
S_TRPS:	LD	(TRBPSG),DE
	RET	
;  ,, with Z80
S_Z80:	LD	HL,PC2OUT
	LD	(PACOUT+1),HL
	LD	HL,MM2OUT
	LD	(MMOUT+1),HL
	LD	HL,PC3OUT
	LD	(FPCOUT+1),HL
	LD	HL,MM3OUT
	LD	(FMMOUT+1),HL
	JP	S_TRPS
;  out routs
MMOUT:	JP	MM2OUT
FMMOUT:	JP	MM3OUT
PACOUT:	JP	PC2OUT
FPCOUT:	JP	PC3OUT
	
MM2OUT:	EX	AF,AF
	LD	A,C
	OUT	($C0),A
	EX	AF,AF
	OUT	($C1),A
	EX	(SP),HL
	EX	(SP),HL
	RET	
PC2OUT:	EX	AF,AF
	LD	A,C
	OUT	($7C),A
	EX	AF,AF
	OUT	($7D),A
	EX	(SP),HL
	EX	(SP),HL
	RET	
MM3OUT:	EX	AF,AF
	LD	A,C
	OUT	($C0),A
	EX	AF,AF
	OUT	($C1),A
	RET	
PC3OUT:	EX	AF,AF
	LD	A,C
	OUT	($7C),A
	EX	AF,AF
	OUT	($7D),A
	RET	
MMROUT:	EX	AF,AF
	CALL	TRBWT
	LD	A,C
	OUT	($C0),A
	IN	A,($E6)
	LD	(RTEL),A
	EX	AF,AF
	OUT	($C1),A
	RET	
PAROUT:	EX	AF,AF
	CALL	TRBWT
	LD	A,C
	OUT	($7C),A
	IN	A,($E6)
	LD	(RTEL),A
	EX	AF,AF
	OUT	($7D),A
	RET	
TRBWT:	PUSH	BC
	LD	A,(RTEL)
	LD	B,A
TRBWL:	IN	A,($E6)
	SUB	B
	CP	7
	JR	C,TRBWL
	POP	BC
	RET	
	
; +----- Stop music -----+
	
STPMUS:	
HLTMUS:	LD	A,(BUSPLY)
	OR	A
	RET	Z
STPMS2:	XOR	A
	LD	(BUSPLY),A
	DI	
HLTMS2:	LD	DE,25
	LD	IY,LASPL1
	LD	B,9
HLTMSL:	CALL	MSXUIT
	CALL	MODUIT
	ADD	IY,DE
	DJNZ	HLTMSL
	XOR	A
	LD	(BUSPLY),A
	EI	
	JP	ENDPSG
MSXUIT:	LD	A,(XSUST)
	BIT	5,A
	JR	Z,MSXUI2
	LD	A,B
	CP	4
	RET	C
MSXUI2:	LD	C,(IY+8)
	XOR	A
	CALL	PACOUT
	LD	A,C
	ADD	A,$10
	LD	C,A
	XOR	A
	JP	FPCOUT
MODUIT:	LD	C,(IY+7)
	XOR	A
	CALL	MMOUT
	SET	4,C
	JP	FMMOUT
	
;  <psg drum data>
PBDDAT:	DB	5,3,0,179,1,6,7,$FE,17
PS1DAT:	DB	6,2,6,$13,7,$F7,15
PS2DAT:	DB	6,2,6,$09,7,$F7,15
PB1DAT:	DB	4,3,0,173,1,1,7,$FE,15
PB2DAT:	DB	4,3,0,72,1,0,7,$FE,15
PH1DAT:	DB	5,2,6,$06,7,$F7,15
PH2DAT:	DB	5,2,6,$01,7,$F7,14
PSGADR:	DW	PBDDAT,PS1DAT,PS2DAT,PB1DAT,PB2DAT,PH1DAT,PH2DAT
PSGCNT:	DB	0
PSGVOL:	DB	0
MAXPSG:	DB	0
	
;  <MSX Audio data>
MMPDT1:	DB	$05,$22,$05,$6A,$05,$BA,$06,$12,$06,$73,$06,$D3
	DB	$07,$3B,$07,$AB,$08,$1B,$08,$9C,$09,$24,$09,$AC
	DB	$0A,$3D,$0A,$D5,$0B,$7D,$0C,$2D,$0C,$E6,$0D,$A6
	DB	$0E,$7F,$0F,$57,$10,$3F,$11,$38,$12,$40,$13,$51
	DB	$14,$7A,$15,$AA,$16,$FB,$18,$5B,$19,$C4,$1B,$4D
	DB	$1C,$FE,$1E,$B6,$20,$77,$22,$70,$24,$81,$26,$AA
	DB	$28,$FC,$2B,$5D,$2D,$F6,$30,$AF,$33,$89,$36,$A2
	DB	$39,$F4,$3D,$66,$40,$F7,$44,$E1,$49,$0B,$4D,$4D
	DB	$51,$F0,$56,$B2,$5B,$EC,$61,$5F,$67,$1A,$6D,$45
	DB	$73,$E8,$7A,$CB,$81,$F0,$89,$C4,$92,$18,$9A,$A4
MMRGAD:	DB	$20,$23,$40,$43,$60,$63,$80,$83,$C0	; k1
	DB	$21,$24,$41,$44,$61,$64,$81,$84,$C1	; k2
	DB	$22,$25,$42,$45,$62,$65,$82,$85,$C2	; k3
	DB	$28,$2B,$48,$4B,$68,$6B,$88,$8B,$C3	; k4
	DB	$29,$2C,$49,$4C,$69,$6C,$89,$8C,$C4	; k5
	DB	$2A,$2D,$4A,$4D,$6A,$6D,$8A,$8D,$C5	; k6
	DB	$30,$33,$50,$53,$70,$73,$90,$93,$C6	; k7
	DB	$31,$34,$51,$54,$71,$74,$91,$94,$C7	; k8
	DB	$32,$35,$52,$55,$72,$75,$92,$95,$C8	; k9
SMPADR:	DW	$00,$9F,$A0,$019F,$01A0,$01FF,$02F4,$047F
	DW	$0480,$07FF,$0800,$0B00,$0B01,$0F00,$0F01,$1601
	DW	$1602,$1A01,$1A02,$1CFF,$1D00,$1FFF,$00,$00
	DW	$00,$00,$00,$00
STRREG:	DB	16,$F0,17,$51,18,255,$18,8,$19,8
	
;  <MSX Music>
PAFREQ:	DB	$AD,$00,$B7,$00,$C2,$00,$CD,$00,$D9,$00,$E6,$00
	DB	$F4,$00,$03,$01,$12,$01,$22,$01,$34,$01,$46,$01
	DB	$AD,$02,$B7,$02,$C2,$02,$CD,$02,$D9,$02,$E6,$02
	DB	$F4,$02,$03,$03,$12,$03,$22,$03,$34,$03,$46,$03
	DB	$AD,$04,$B7,$04,$C2,$04,$CD,$04,$D9,$04,$E6,$04
	DB	$F4,$04,$03,$05,$12,$05,$22,$05,$34,$05,$46,$05
	DB	$AD,$06,$B7,$06,$C2,$06,$CD,$06,$D9,$06,$E6,$06
	DB	$F4,$06,$03,$07,$12,$07,$22,$07,$34,$07,$46,$07
	DB	$AD,$08,$B7,$08,$C2,$08,$CD,$08,$D9,$08,$E6,$08
	DB	$F4,$08,$03,$09,$12,$09,$22,$09,$34,$09,$46,$09
	DB	$AD,$0A,$B7,$0A,$C2,$0A,$CD,$0A,$D9,$0A,$E6,$0A
	DB	$F4,$0A,$03,$0B,$12,$0B,$22,$0B,$34,$0B,$46,$0B
	DB	$AD,$0C,$B7,$0C,$C2,$0C,$CD,$0C,$D9,$0C,$E6,$0C
	DB	$F4,$0C,$03,$0D,$12,$0D,$22,$0D,$34,$0D,$46,$0D
	DB	$AD,$0E,$B7,$0E,$C2,$0E,$CD,$0E,$D9,$0E,$E6,$0E
	DB	$F4,$0E,$03,$0F,$12,$0F,$22,$0F,$34,$0F,$46,$0F
DRMREG:	DB	$36,$37,$38,$16,$26,$17,$27,$18,$28
	
LASPL1:	DB	0,0,0,0,0,0,0,$A0,$10,0,0,0,$30,$43,0,0,0,0,0,0,0,0,0,0,0
	DB	0,0,0,0,0,0,0,$A1,$11,0,0,0,$31,$44,0,0,0,0,0,0,0,0,0,0,0
	DB	0,0,0,0,0,0,0,$A2,$12,0,0,0,$32,$45,0,0,0,0,0,0,0,0,0,0,0
	DB	0,0,0,0,0,0,0,$A3,$13,0,0,0,$33,$4B,0,0,0,0,0,0,0,0,0,0,0
	DB	0,0,0,0,0,0,0,$A4,$14,0,0,0,$34,$4C,0,0,0,0,0,0,0,0,0,0,0
	DB	0,0,0,0,0,0,0,$A5,$15,0,0,0,$35,$4D,0,0,0,0,0,0,0,0,0,0,0
	DB	0,0,0,0,0,0,0,$A6,$16,0,0,0,$36,$53,0,0,0,0,0,0,0,0,0,0,0
	DB	0,0,0,0,0,0,0,$A7,$17,0,0,0,$37,$54,0,0,0,0,0,0,0,0,0,0,0
	DB	0,0,0,0,0,0,0,$A8,$18,0,0,0,$38,$55,0,0,0,0,0,0,0,0,0,0,0
	
;  <Overal>
CHNWC1:	DW	0,0,0,0,0
MODVAL:	DW	1,2,2,-2,-2,-1,-2,-2,2,2
MMFRQS:	DB	0
TPVAL:	DB	0
SPEED:	DB	0
SPDCNT:	DB	0
RTEL:	DB	0
PATADR:	DW	0
PATPNT:	DW	0
XPOS:	DW	0
SMPVLM:	DB	0
FADING:	DB	0
FADSPD:	DB	12
FADCNT:	DB	0
	
;  <copie music settings>
XLENG:	DS	3
XMMVOC:	DS	16*9
XMMSTI:	DS	16
XPASTI:	DS	32
XSTPR:	DS	10
XTEMPO:	DS	1
XSUST:	DS	1
XBEGVM:	DS	9
XBEGVP:	DS	9
XORGP1:	DS	6*8
XORGNR:	DS	6
XSMPKT:	DS	8
XDRBLK:	DS	15
XDRVOL:	DS	3
XDRFRQ:	DS	20
XREVER:	DS	9
XLOOP:	DS	1
FRQCNT:	DB	6	;  60 Hz counter
	END	

By JohnHassink

Ambassador (5591)

JohnHassink's picture

04-06-2009, 13:04

GREAT ro! Thanks a lot!!!

By ro

Scribe (4544)

ro's picture

04-06-2009, 14:14

no worries. it is the original replayer with a few adjustments. But you should just check it yourself. have fun!

By Huey

Prophet (2676)

Huey's picture

04-06-2009, 14:15

....
XMMVOC:	DS	16*9
:	DS	16
XPASTI:	DS	32
......

WTF is that blocky thing?

By ro

Scribe (4544)

ro's picture

04-06-2009, 15:13

whoops, that must be a label called "XMMSTI:"

{mod: changed it in the source}

Page 3/3
1 | 2 |