Remember in the '80 Dragon's Lair in arcade, was one of those famous Cabinet including a Laserdisc player...
Today I propose you to have the same feeling, with your MSX !
What do you need ?
-1 x Sony HBG900 MSX Computer
-1 x Denon DVD Player DVD-2930
-1 x DVD of Dragon's Lair (Version for DVD player, not DVD-ROM version)
-1 x RS232 Cable. DB25<->DB9 (Male/male)
How to do ?
- Connect your MSX Sony HBG900 to a Monitor
- Connect you DVD Player to a TV
- Connect RS232 Cable between Your MSX and The DENON 2930
- Put the DVD in the player
- Load this program into the MSX and Run it
10 REM DRAGON'S LAIR - DVD CONTROL by ERICB59 - 2014
20 ' SET VIDEO 2,0,0,1,3,1,1:COLOR ,0:CLS
30 CALL COMINI("0:8E1NNNNN",9600,9600)
40 OPEN "com0:" FOR OUTPUT AS #1
50 DIM D$(8):KEY OFF
60 ON STOP GOSUB 210:STOP ON
70 RESTORE 330:FOR I=1TO9:READ A$:PL$=PL$+CHR$(VAL("&H"+A$)):NEXT I
80 RESTORE 230:FOR I=1TO9:READ A$:D$(7)=D$(7)+CHR$(VAL("&H"+A$)):NEXT I
90 RESTORE 250:FOR I=1TO9:READ A$:D$(1)=D$(1)+CHR$(VAL("&H"+A$)):NEXT I
100 RESTORE 270:FOR I=1TO9:READ A$:D$(3)=D$(3)+CHR$(VAL("&H"+A$)):NEXT I
110 RESTORE 290:FOR I=1TO9:READ A$:D$(5)=D$(5)+CHR$(VAL("&H"+A$)):NEXT I
120 RESTORE 310:FOR I=1TO9:READ A$:E$=E$+CHR$(VAL("&H"+A$)):NEXT I
130 RESTORE 350:FOR I=1TO9:READ A$:M$=M$+CHR$(VAL("&H"+A$)):NEXT I
140 RESTORE 370:FOR I=1TO9:READ A$:PA$=PA$+CHR$(VAL("&H"+A$)):NEXT I
150 PRINT #1,PL$
160 STRIG(0) ON
170 S=STICK(0):T=STRIG(0)
180 IF S THEN PRINT #1,D$(S):PRINT D$(S):FOR I=1TO500:NEXTI
190 IF T THEN PRINT #1,E$:PRINT E$:FOR I=1TO500:NEXT I
200 GOTO 170
210 PRINT #1,M$:CLOSE #1
220 END
230 REM left
240 DATA 02,4d,31,00,00,00,03,38,31
250 REM up
260 DATA 02,4d,32,00,00,00,03,38,32
270 REM right
280 DATA 02,4d,33,00,00,00,03,38,33
290 REM down
300 DATA 02,4d,34,00,00,00,03,38,34
310 REM enter
320 DATA 02,4e,00,00,00,00,03,35,31
330 REM play
340 DATA 02,40,00,00,00,00,03,34,33
350 REM Menu
360 DATA 02,46,00,00,00,00,03,34,39
370 REM pause
380 DATA 02,42,00,00,00,00,03,34,35
Now the DVD player run, and you control the player with your MSX Keyboard
Up/Right/down/left and Space
Do the right move to continue the game !
here a video preview
https://www.youtube.com/watch?v=7UF4ZY2cDdg
With the Sony HBG900 You can also use only one monitor, if you use the Superimpose fonction,
so remove the Rem on line 20, and connect Video out of the DVD player to the Video In of the HBG900.
This code may work on other MSX computers with RS232 interface, with only small changes.
enjoy !

