Secret keyboard sequence

Let me help:

CHSNS   EQU     #9C
CHGET   EQU     #9F


KEYWORD_SCAN:   ; Insert call to this to your H.TIMI (#FD9F) interrupt handler

        CALL    CHSNS
        RET     Z
        CALL    CHGET
        CP      #D             ;RETURN
        JR      Z,.CHECK_COMMANDS

        CALL    .UPPER_CASE

        LD      HL,BUFFER_END-1
        LD      DE,(BUFFER_POINTER)
        LD      (DE),A
        INC     DE
        XOR     A
        LD      (DE),A
        SBC     HL,DE
        RET     Z
        LD      (BUFFER_POINTER),DE
        RET


.CHECK_COMMANDS:
	LD	HL,.CMDS        ; Table with valid commands
        CALL    .CHECK_BUFFER
	LD	HL,BUFFER_START
        LD      (BUFFER_POINTER),HL
        LD      (HL),0
        RET

.CHECK_BUFFER:
	LD	DE,BUFFER_START
.CHECK_LOOP:
        LD	A,(DE)
	CPI
	JR	NZ,.TO_NEXT_CMD	; Not equal
	INC	DE
	AND	A
	JR	NZ,.CHECK_LOOP	; No end of instruction name, go checking
	LD	E,(HL)
	INC	HL
	LD	D,(HL)
        POP     HL
        PUSH    DE
        JP      (HL)

.TO_NEXT_CMD:
	LD	C,0FFH
	XOR	A
	DEC     HL
	CPIR			; Skip to end of instruction name
	INC	HL
	INC	HL		; Skip address
	CP	(HL)
	JP	NZ,.CHECK_BUFFER; Not end of table, go checking
	RET

.UPPER_CASE:
        CP      "a"
        RET     C
        CP      "z"+1
        RET     NC
        AND     %11011111
        RET

;---------------------------
.CMDS:

; List of available instructions (as ASCIIZ) and execute address (as word)

	DEFB	"BEEP",0
	DEFW	#C0            ; Say beep

	DEFB	"MUSIC TEST",0
	DEFW	MUSIC_TEST_ROUTINE

	DEFB    "I CHEAT",0
	DEFW    ENABLE_ENDLESS_LIFES

	DEFB	0               ; No more commands

 ;---------------------------

BUFFER_POINTER:
        DEFW    BUFFER_START

BUFFER_START:
        DEFS    16
BUFFER_END:

Nice !
Thank you, I'll save that snippet of code.

My routine works from ROM just as well as from RAM, but naturally you need to move BUFFER_POINTER, BUFFER_START and BUFFER_END to point to RAM... just as you did on your code... I just added these after the code to demonstrate how BUFFER_POINTER should be initialized. (As you probably realized already, you have to do it in init phase to avoid random addresses to be potentially overwritten)

Quickly reading it, it seems that you have adjusted the input logic a bit and then re-implemented rest of the functionality in somewhat longer & slower way.

In your code I can see at least one potential problem that may trigger when the implementation is complete... If you type "musictest" and hit RETURN the music test part will start... Now if you don't specifically disable this keyword system and you hit RETURN again the music test part will reboot... Although it is not much of a real problem, this is probably not what you wanted... Naturally if you want the keyword system to be active only ie. in title screen and not all the time the game is running then you will not see this problem... you just then need to include a way to disable this routine.

You either have to disable this routine or put the "no_cmd" part to the beginning of "music_test" because other ways it will detect the keyword from buffer when return is pressed again... Executing it at end of the music_test is too late as user can hit return WHILE the test is executing.

Well, I expected that you have already a htimi handler that saves AF as you probably play music n' stuff... If that is not the case, then you can make one like:

INTHANDLER:
	PUSH AF
	CALL KEYWORD_SCAN
	POP AF
	RET

Well, just like with ".CMDS" I use ASCIIZ strings in buffer (= Zero terminated ASCII). As you may see, I don't ever clear the buffer, so it may contain random stuff and therefore I need a character to separate valid data from old trash data... You do practically same thing by clearing ALL of the buffer back to 0... but 1 byte is enough as you terminate the check anyway to first 0.

The "JP (HL)" is a bit nasty instruction as it has "wrong syntax" compared to what it does... the correct syntax would be "JP HL"... Practically if you do POP HL & JP (HL), it has same effect as with RET (except that the return address is then also placed to HL)... Now what I do here is therefore just swapping the execution order... I first POP the return address that was placed there by "CALL .CHECK_BUFFER", then I replace that return address with routine starting address that I got from ".CMDS" table. How ever as I explained at the top, I need to reset the buffer BEFORE the routine is executed, so I jump to the address that was POP:ed (routine after the CALL that resets the buffer) and then when that routine ends with RET it will actually start the routine that was read from the table.

As long as it is this simple, you are not planning any story telling or animations, it really does not matter how you do this stuff... You can just as well forget the whole interrupt thing and just add "CALL KEYWORD_SCAN" after "CALL PLY_AKG_PLAY" and be done with it... You can add interrupt handler later if your plan becomes more complex.