Retrospectiva 2012 - Cast your votes!

by the_woz on 19-04-2013, 12:23
Topic: Challenges
Languages:

Retrospectiva 2012 has closed with 13 artworks and 18 games, including 2 MSX releases (Splink and REC). Now it's time to vote for the winners!

To make things easy, all entries can be downloaded with two files, the Retrospectiva 2012 graphics pack and the Retrospectiva 2012 BASIC games pack. Once you have had a look at the entries, you can cast your votes on the graphics vote page and/or the games vote page. Voting is possible until April 24th, 0:00 (UTC -3).

Relevant link: Retrospectiva 2012 - Graphics vote page
Relevant link: Retrospectiva 2012 - Games vote page

Comments (3)

By Meits

Scribe (5347)

Meits's picture

19-04-2013, 16:54

REC: Don't understand what it is/does...
Splink: Ain't got a data recorder

No votes for me oO

By mars2000you

Enlighted (5467)

mars2000you's picture

19-04-2013, 16:58

Here's the listing, you can create a DSK !

10 BEST=100
20 KEY OFF
30 CLS
40 SCREEN 2
50 OPEN "GRP:" AS 1
60 COLOR 15,1,1
70 Z=RND(-TIME)
80 REM SET UP ARRAYS
90 REM IP=4 KEYS IN PLAY
100 DIM IP(4)
110 REM YX & YY=YOU CO-ORDS
120 DIM YX(4), YY(4)
130 REM OX & OY=YOUR OLD X,Y
140 DIM OX(4), OY(4)
150 REM I$=IMAGE FOR KEYS
160 DIM I$(4)
170 REM TX & TY=TARGET CO-ORDS
180 DIM TX(4), TY(4)
190 REM T$=IMAGE FOR TARGETS
200 DIM T$(4)
210 REM EX & EY=CO-ORDS FOR ENEMIES
220 DIM EX(20), EY(20)
230 REM PX & PY=POWERUP TO DESTROY 'X'
240 DIM PX(4), PY(4)
250 REM MX & MY=MORE TIME
260 DIM MX(10), MY(10)
270 REM MAP=MAP COORDS
280 DIM MAP(29,21)
290 REM NEW GAME LOOP START
300 COLOR 2,1,1
310 CLS
320 SCREEN 2
330 CL=2
340 COLOR CL,1
350 PRESET (13*8,5*8)
360 PRINT#1,"SPLINK"
370 PRESET(6*8,20*8)
375 COLOR 4,1
380 PRINT#1,"APrimitive8 (2013)"
385 COLOR 2,1
390 PRESET(7*8,10*8)
400 PRINT#1,"[SPACE] START
410 PRESET(7*8,12*8)
420 PRINT#1,"[I] INSTRUCTIONS"
430 PRESET(7*8,14*8)
440 PRINT#1,"[X] QUIT
450 K$=INKEY$
460 IF K$=" " THEN 790
470 IF K$="x" THEN END
480 IF K$="i" THEN 550
490 CL=CL+1
500 IF CL>15 THEN CL=2
510 COLOR CL,1
520 PRESET (13*8,5*8)
530 PRINT#1,"SPLINK"
540 GOTO 450
550 REM Instructions here
560 CLS:PRESET(2*8,9*8)
570 COLOR 2,1
580 PRESET(10*8,1*8)
590 PRINT#1,"INSTRUCTIONS"
600 PRESET(0*8,5*8)
610 COLOR 4,1,1
620 PRINT#1,"Guide ";CHR$(1)+CHR$(&H43);" ";CHR$(1)+CHR$(&H44);" "+CHR$(1)+CHR$(&H45);" ";CHR$(1)+CHR$(&H46);" to their targets."
625 COLOR 15,1
630 PRESET(0*8,7*8)
640 PRINT#1,"Use 1234 to move & 0 to stop."
645 COLOR 10,1
650 PRESET(0*8,9*8)
660 PRINT#1,"Collect ";CHR$(&HE8);" for time bonus."
665 COLOR 8,1
670 PRESET(0*8,11*8)
680 PRINT#1,"Avoid skulls."
685 COLOR 13,1
690 PRESET(0*8,13*8)
700 PRINT#1,CHR$(&HEC);" protect you from skulls."
705 COLOR 7,1
710 PRESET(0*8,15*8)
720 PRINT#1,"Quick game/low score = Best."
730 PRESET(9*8,20*8)
740 COLOR 2,1
750 PRINT#1,"[M] MAIN MENU"
760 K$=INKEY$
770 IF K$="m" THEN 310
780 GOTO 760
790 REM Game set up
800 TN$="T110O5L16BR16AR16GR16AR16GR16FR16GR16FR16ER16GR16AR16BR16"
801 TM$="T110O5L16BR16AR16GR16AR16GR16FR16GR16AR16BR16AR16BR16AR16"
810 COLOR 8,1
811  PRESET(11*8,17*8)
812 PRINT#1,"GET READY!"
815 REM Create empty map
820 FOR A=1 TO 29
830 FOR B=1 TO 21
840 MAP(A,B)=0
850 NEXT B
860 NEXT A
870 SCREEN 2
880 CLS
885 PLAY "V15XTN$;XTM$;","V12R32XTN$;XTM$;"
890 COLOR 15,1,1
900 G=0
910 POW=0
920 SC=0
930 TB=0 : REM Time Bonus
940 FOR A=1 TO 4
950 IP(A)=1
960 NEXT A
965 REM Assign char to you
970 I$(1)=CHR$(1)+CHR$(&H43)
980 I$(2)=CHR$(1)+CHR$(&H44)
990 I$(3)=CHR$(1)+CHR$(&H45)
1000 I$(4)=CHR$(1)+CHR$(&H46)
1010 T$(1)=CHR$(1)+CHR$(&H43)
1020 T$(2)=CHR$(1)+CHR$(&H44)
1030 T$(3)=CHR$(1)+CHR$(&H45)
1040 T$(4)=CHR$(1)+CHR$(&H46)
1045 REM Draw vars & border
1050 COLOR 15,1
1060 PRESET (0*8,1*8)
1070 PRINT#1,"BEST"
1080 PRESET (0*8,3*8)
1090 PRINT#1,BEST
1100 PRESET (0*8,6*8)
1110 PRINT#1,"TIME"
1120 COLOR 13,1
1130 PRESET (0*8,10*8)
1140 PRINT#1,CHR$(&HEC);" ";POW
1150 COLOR 10,1
1160 PRESET (0*8,12*8)
1170 PRINT#1,CHR$(&HE8);" ";TB
1180 COLOR 2,1
1190 FOR A=7 TO 29
1200 PRESET (A*8,0*8)
1210 PRINT#1,CHR$(&HCE)
1220 PRESET (A*8,21*8)
1230 PRINT#1,CHR$(&HCD)
1240 NEXT A
1250 FOR A=1 TO 20
1260 PRESET (6*8,A*8)
1270 PRINT#1,CHR$(&HD0)
1280 PRESET (30*8,A*8)
1290 PRINT#1,CHR$(&HCF)
1300 NEXT A
1310 COLOR 8,1
1320 REM Select & plot enemy positions
1330 FOR A=1 TO 20
1340 EX(A)=RND(1)
1350 EX(A)=INT(22*EX(A))+7
1360 EY(A)=RND(1)
1370 EY(A)=INT(20*EY(A))+1
1380 IF MAP(EX(A),EY(A))<>0 THEN GOTO 1340
1390 MAP(EX(A),EY(A))=1
1400 PRESET (EX(A)*8,EY(A)*8)
1401 DRAW"c1r1c8r5f1d2l7u2r6d1l1c1l1c8l2c1l1c8d1f1r3f1r1l1g1l3h1l1r1f1g1l1r1e1r3f1r1"
1410 REM PRINT#1,CHR$(&H23)
1420 NEXT A
1430 COLOR 4,1
1440 FOR A=1 TO 4
1450 YX(A)=RND(1)
1460 YX(A)=INT(22*YX(A))+7
1470 YY(A)=RND(1)
1480 YY(A)=INT(20*YY(A))+1
1490 IF MAP(YX(A),YY(A))<>0 THEN GOTO 1450
1500 MAP(YX(A),YY(A))=2
1510 PRESET (YX(A)*8,YY(A)*8)
1520 PRINT#1,I$(A)
1530 NEXT A
1540 COLOR 2,1
1550 FOR A=1 TO 4
1560 TX(A)=RND(1)
1570 TX(A)=INT(22*TX(A))+7
1580 TY(A)=RND(1)
1590 TY(A)=INT(20*TY(A))+1
1600 IF MAP(TX(A),TY(A))<>0 THEN GOTO 1560
1610 MAP(TX(A),TY(A))=3
1620 PRESET(TX(A)*8,TY(A)*8)
1630 PRINT#1,T$(A)
1640 NEXT A
1650 COLOR 13,1
1660 FOR A=1 TO 4
1670 PX(A)=RND(1)
1680 PX(A)=INT(22*PX(A))+7
1690 PY(A)=RND(1)
1700 PY(A)=INT(20*PY(A))+1
1710 IF MAP(PX(A),PY(A))<>0 THEN GOTO 1670
1720 MAP(PX(A),PY(A))=4
1730 PRESET(PX(A)*8,PY(A)*8)
1740 PRINT#1,CHR$(&HEC)
1750 NEXT A
1760 COLOR 10,1
1770 FOR A=1 TO 10
1780 MX(A)=RND(1)
1790 MX(A)=INT(22*MX(A))+7
1800 MY(A)=RND(1)
1810 MY(A)=INT(20*MY(A))+1
1820 IF MAP(MX(A),MY(A))<>0 THEN GOTO 1780
1830 MAP(MX(A),MY(A))=5
1840 PRESET(MX(A)*8,MY(A)*8)
1850 IF K$="x" THEN END
1860 PRINT#1,CHR$(&HE8)
1870 NEXT A
1880 MV=0
1890 TM=TIME
1900 REM Game Loop
1910 K$=INKEY$
1920 IF K$="1" THEN MV=1
1930 IF K$="2" THEN MV=2
1940 IF K$="3" THEN MV=3
1950 IF K$="4" THEN MV=4
1960 IF K$="0" THEN MV=0
1970 IF K$="x" THEN 290
1980 IF MV<>0 THEN GOSUB 2110
1990 IF MV=1 THEN GOSUB 2160
2000 IF MV=2 THEN GOSUB 2220
2010 IF MV=3 THEN GOSUB 2280
2020 IF MV=4 THEN GOSUB 2340
2030 REM Print Time
2040 PRESET(0*8,8*8)
2050 COLOR 1,1
2060 PRINT#1,CHR$(&HDB)+CHR$(&HDB)+CHR$(&HDB)+CHR$(&HDB)+CHR$(&HDB)
2070 TN=TIME
2080 PRESET(0*8,8*8): COLOR 12,1
2090 PRINT#1,INT((TN-TM)/50)
2100 GOTO 1910
2110 FOR A=1 TO 4
2120 OX(A)=YX(A)
2130 OY(A)=YY(A)
2140 NEXT A
2150 RETURN
2160 IF IP(1)=1 THEN YX(1)=YX(1)-1
2170 IF IP(2)=1 THEN YX(2)=YX(2)+1
2180 IF IP(3)=1 THEN YY(3)=YY(3)-1
2190 IF IP(4)=1 THEN YY(4)=YY(4)+1
2200 GOSUB 2400
2210 RETURN
2220 IF IP(1)=1 THEN YX(1)=YX(1)+1
2230 IF IP(2)=1 THEN YX(2)=YX(2)-1
2240 IF IP(3)=1 THEN YY(3)=YY(3)+1
2250 IF IP(4)=1 THEN YY(4)=YY(4)-1
2260 GOSUB 2400
2270 RETURN
2280 IF IP(1)=1 THEN YY(1)=YY(1)-1
2290 IF IP(2)=1 THEN YY(2)=YY(2)+1
2300 IF IP(3)=1 THEN YX(3)=YX(3)-1
2310 IF IP(4)=1 THEN YX(4)=YX(4)+1
2320 GOSUB 2400
2330 RETURN
2340 IF IP(1)=1 THEN YY(1)=YY(1)+1
2350 IF IP(2)=1 THEN YY(2)=YY(2)-1
2360 IF IP(3)=1 THEN YX(3)=YX(3)+1
2370 IF IP(4)=1 THEN YX(4)=YX(4)-1
2380 GOSUB 2400
2390 RETURN
2400 FOR A=1 TO 4
2410 IF YX(A)<7 THEN YX(A)=29
2420 IF YX(A)>29 THEN YX(A)=7
2430 IF YY(A)<1 THEN YY(A)=20
2440 IF YY(A)>20 THEN YY(A)=1
2450 COLOR 4,1
2460 PRESET(YX(A)*8,YY(A)*8)
2470 PRINT#1,I$(A)
2480 COLOR 1,1
2490 PRESET(OX(A)*8,OY(A)*8)
2500 PRINT#1,CHR$(&HDB)
2510 NEXT A
2520 REM Draw Target if IP=1
2530 FOR A=1 TO 4
2540 IF IP(A)<>1 THEN 2580
2550 COLOR 2,1
2560 PRESET(TX(A)*8,TY(A)*8)
2570 PRINT#1,T$(A)
2580 NEXT A
2590 FOR A=1 TO 4
2600 IF YX(A)=TX(A) AND YY(A)=TY(A) AND I$(A)<>CHR$(&H1)+CHR$(&H41) THEN GOTO 3400
2610 IF MAP(YX(A),YY(A))=4 THEN GOTO 2670
2620 IF MAP(YX(A),YY(A))=1 THEN GOTO 2860
2630 IF MAP(YX(A),YY(A))=5 THEN GOTO 3230
2640 IF G=4 THEN GOTO 3530
2650 NEXT A
2660 RETURN
2670 REM Powerup
2680 PT$="O4L32FGAGAGFA"
2685 PLAY"V15XPT$;","V12R64XPT$;"
2690 PRESET(YX(A)*8,YY(A)*8)
2700 COLOR 1,1:PRINT#1,CHR$(1)+CHR$(&HDB)
2710 FOR LP=2 TO 6
2730 PRESET(YX(A)*8,YY(A)*8)
2740 COLOR LP,1
2750 PRINT#1,CHR$(1)+CHR$(&H4F)
2760 NEXT LP
2770 POW=POW+1
2780 MAP(YX(A),YY(A))=0
2790 COLOR 1,1
2800 PRESET(2*8,10*8)
2810 PRINT#1,CHR$(&HDB)+CHR$(&HDB)+CHR$(&HDB)
2820 COLOR 15,1
2830 PRESET(2*8,10*8)
2840 PRINT#1,POW
2850 GOTO 2650
2860 REM Hit enemy
2870 IF POW<1 THEN GOTO 3070
2880 PLAY"O4L16ABCD"
2890 PRESET(YX(A)*8,YY(A)*8)
2900 COLOR 1,1
2910 PRINT#1,CHR$(&HDB)
2920 POW=POW-1
2930 FOR LP=2 TO 6
2940 PRESET(YX(A)*8,YY(A)*8)
2950 COLOR LP,1
2960 PRINT#1,CHR$(1)+CHR$(&H4F)
2980 NEXT LP
2990 COLOR 1,1
3000 PRESET(2*8,10*8)
3010 PRINT#1,CHR$(&HDB)+CHR$(&HDB)+CHR$(&HDB)
3020 COLOR 15,1
3030 PRESET(2*8,10*8)
3040 PRINT#1,POW
3050 MAP(YX(A),YY(A))=0
3060 GOTO 2650
3070 I$(A)=CHR$(1)+CHR$(&H5C)
3080 TF$="O2L16CR16CER16DFR16"
3085 PLAY"V15XTF$;","V12R32XTF$;"
3090 PRESET(YX(A)*8,YY(A)*8)
3100 COLOR 1,1
3110 PRINT#1,CHR$(&HDB)
3130 FOR LP=2 TO 6
3140 PRESET(YX(A)*8,YY(A)*8)
3150 COLOR LP,1
3160 PRINT#1,CHR$(1)+CHR$(&H5C)
3180 NEXT LP
3190 IP(A)=0
3200 MAP(YX(A),YY(A))=0
3210 G=G+1
3220 GOTO 2640
3230 REM More time
3231 PRESET(YX(A)*8,YY(A)*8)
3232 COLOR 1,1
3233 PRINT#1,CHR$(&HDB)
3235 TB$="O5L32CGDAEBDA"
3236 PLAY"V15XTB$;","V12R64XTB$;"
3240 FOR LP=2 TO 6
3250 PRESET(YX(A)*8,YY(A)*8)
3260 COLOR LP,1
3270 PRINT#1,CHR$(1)+CHR$(&H4F)
3290 NEXT LP
3300 TB=TB+1
3310 COLOR 1,1
3320 PRESET(2*8,12*8)
3330 PRINT#1,CHR$(&HDB)+CHR$(&HDB)+CHR$(&HDB)
3340 COLOR 15,1
3350 PRESET(2*8,12*8)
3360 PRINT#1,TB
3370 MAP(YX(A),YY(A))=0
3390 GOTO 2650
3400 REM REACHED TARGET
3410 I$(A)=CHR$(&H1)+CHR$(&H41)
3420 IP(A)=0
3425 TG$="O5L16BGR16BGR16AF"
3430 PLAY"V15XTG$;","V12R32XTG$;"
3431 PRESET(YX(A)*8,YY(A)*8)
3432 COLOR 1,1
3433 PRINT#1,CHR$(&HDB)
3440 FOR LP=2 TO 6
3450 PRESET(YX(A)*8,YY(A)*8)
3460 COLOR LP,1
3470 PRINT#1,CHR$(1)+CHR$(&H41)
3490 NEXT LP
3500 G=G+1
3510 GOTO 2640
3520 END
3530 REM ALL 4 KEYS IP=0
3540 TR=0
3550 TE$="L16O4CDEFEDEFGFEDEFGB"
3555 PLAY"V15XTE$;","V12R32XTE$;"
3560 FOR A=1 TO 4
3570 IF I$(A)=CHR$(&H1)+CHR$(&H41) THEN TR=TR+1
3580 NEXT A
3590 ET=INT((TN-TM)/50)
3600 COLOR 1,1
3610 LINE(56,8)-(232,160),1,BF
3620 COLOR 4,1
3630 PRESET(12*8,4*8)
3640 PRINT#1,"TIME:";ET
3650 PRESET(12*8,6*8)
3660 PRINT#1,"-";CHR$(&HE8);"x5:";TB*5
3670 PRESET(12*8,8*8)
3680 PRINT#1,"+";CHR$(&HEC);"x10:";POW*10
3690 PRESET(12*8,10*8)
3700 PRINT#1,CHR$(1)+CHR$(&H41)+" SUCCESS:";TR
3710 SC=(ET-(TB*5)+(POW*10))*(5-TR)
3720 PRESET(12*8,14*8)
3730 PRINT#1,"SCORE:";SC
3740 IF SC>BEST THEN 3820
3750 BEST=SC
3760 FOR A=1 TO 15
3770 PRESET(8*8,16*8)
3780 PRINT#1,"WAY TO GO! BEST SCORE!"
3790 COLOR A,1,A
3800 FOR B=1 TO 100: NEXT B
3810 NEXT A
3820 FOR A=1 TO 1000:NEXT A
3830 GOTO 290


By snout

Ascended (15187)

snout's picture

19-04-2013, 17:36

C'mon, Meits! In the old days we used to toy around with incomprehensible Japanese RPGs and find our way through it, this shouldn't be so hard. Just re-play what "Simon" plays and you'll do fine! Smile

My MSX profile